[Unity-Shader] Blinn-Phong

스펙큘러 표현 공식은 다양하지만 가장 유명하고 전통적인 방식은 Phong반사 입니다.

이 공식의 기본 원리는

"내가 보는 방향으로부터 반사된 방향에 조명이 있으면 그 부분의 하이라이트가 가장 높다" 입니다.

Blinn-Phong의 공식은

"시선 벡터와 조명 벡터의 중간값인 '하프 벡터'를 구하고, 이를 노멀 벡터와 내적한다."

그렇다하면 하프 벡터는 어떻게 구할 수 있을까요?

벡터의 특징중에 하나를 살펴보면 "길이가 같은 두 벡터를 더 하면, 두 벡터 사이의 절반인 각도가 나온다" 라는 특징이 있습니다.

이를 통해 하프 벡터는 "시선 벡터" 와 "조명 벡터" 를 더 하고 이를 normalize 해주면 됩니다.

 

Shader "Custom/CustomBlinnPhong"
{
    Properties
    {
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
        _specCol("SpecColor",Color) = (1,1,1,1)
        _specPow("SpecPow",Range(10,100)) = 100
    }
    SubShader
    {
        Tags { "RenderType"="Opaque" }
        LOD 200
 
        CGPROGRAM
        // Physically based Standard lighting model, and enable shadows on all light types
        #pragma surface surf Test
 
 
        sampler2D _MainTex;
        float _specPow;
        float4 _specCol;
 
        struct Input
        {
            float2 uv_MainTex;
        };
 
        void surf (Input IN, inout SurfaceOutput o)
        {
            // Albedo comes from a texture tinted by color
            fixed4 c = tex2D (_MainTex, IN.uv_MainTex);
            o.Albedo = c.rgb;
            o.Alpha = c.a;
        }
 
        float4 LightingTest(SurfaceOutput s, float3 lightDir,float3 viewDir, float3 atten)
        {
            float3 DiffColor;
            float ndotl = saturate(dot(s.Normal,lightDir));
            float4 final;
 
            float3 SpecColor;
            float3 H = normalize(lightDir+viewDir);
            float spec = saturate(dot(H,s.Normal));
            spec = pow(spec,_specPow);
            SpecColor = spec * _specCol.rgb;
 
            DiffColor = ndotl * s.Albedo * _LightColor0.rgb * atten;
            final.rgb = DiffColor + SpecColor.rgb;
            final.a = s.Alpha;
 
            return final;
        }
        ENDCG
    }
    FallBack "Diffuse"
}
 

전체 소스입니다. 기본 Lamvert 라이트에 Spec을 추가한 연산입니다.

 

float3 SpecColor;
float3 H = normalize(lightDir+viewDir);
float spec = saturate(dot(H,s.Normal));
spec = pow(spec,_specPow);
SpecColor = spec * _specCol.rgb;

 

이러한 형태가 나오게 될 것입니다.